Tal vez no lo sepas, pero en Google Sheets hay todo un lenguaje alrededor del formato de número personalizado con el cual podemos agregar unidades, separador de miles y decimales, notación científica y mucho más. Dar formato es una de las primeras cosas que aprendemos a hacer en documentos y hojas de cálculo, pero hoy vamos a ir un paso más allá de lo básico para aprender usar el formato avanzado para que nuestros números se vean exactamente como los queramos.
Formato de número personalizado
Empecemos con algo sencillo en un documento nuevo de Google Sheets. Tomemos un número cualquiera en una celda, por ejemplo el 10000.
Supongamos que requerimos mostrar este número con una unidad de peso, como kg (es decir, kilogramos). Podríamos simplemente escribir el número y el texto en la celda, pero eso no nos funcionará cuando necesitemos hacer cálculosdespués, porque esencialmente habremos creado una cadena de texto sobre la cual no se puede operar.
Para lograr nuestro objetivo de mostrar el número con una unidad personalizada sin tener que convertirlo en texto y tampoco tener que usar la celda adyacente, seleccionamos la celda y vamos al menú Formato – Número – Formato de número personalizado
Ahí escribimos lo siguiente:
# "kg"
Y damos click en Aplicar.
Fíjate cómo, aunque en la celda dice “kg” al final, en el valor real que se ve en la barra de fórmulas, en realidad seguimos teniendo el número original, osea 10000. Interesante, ¿no? Esto realmente ya lo hemos visto antes muchas veces cuando hemos usado el formato de moneda para agregar los signos de número, pues se trata de lo mismo: un formato nada más. La diferencia ahora es que ahora seguiremos aprendiendo cómo personalizar este formato para ajustarlo a nuestras necesidades exactas.
Si queremos que el número tenga separador de miles, volvemos al menú de Formato – Número – Formato de número personalizado, y ahora escribimos:
#,# "kg"
Separador de miles y decimales (punto o coma) dependiendo del país
De nuevo, nuestro número original no ha cambiado, solamente es el formato lo que estamos cambiando. Esto es importante volverlo a señalar porque en este caso aunque indicamos que se debe mostrar el separador de miles con una coma, el resultado cambiará dependiendo de nuestra configuración regional. En países como España o Colombia, por ejemplo, el separador de miles es un punto y el separador de decimales es una coma. Esto lo encontramos fácilmente en Archivo – Configuración – Configuración regional, eligiendo el país que nos corresponda. En mi caso será México, pero si temporalmente cambio a Colombia, el formato se mostrará distinto aunque el número sea el mismo.
Para efectos de los siguientes ejemplos, estaré usando la configuración de México, es decir, punto para decimal y coma para separador de miles.
Bases y reglas del formato de número personalizado
Antes de seguir, vamos a explicar un poco las bases del formato de número personalizado. Ahora mismo ya utilizamos el signo de número # para indicar un dígito en el número. Este dígito no mostrará ceros insignificantes. Cero insignificante quiere decir que a veces necesitamos mostrar ceros aun cuando no aportan nada al número como tal, sino que funcionan para permitirnos leerlo más fácilmente. Por ejemplo un “cero a la izquierda” no afecta el valor de un número cuando lo escribimos, y usualmente no lo hacemos, pero en casos como monedas, siempre tenemos opcionalmente un cero insigificante antes del punto, y dos ceros insignificantes después del punto.
$20.00
Entonces, si en vez del signo de número # usamos 0, estamos indicando que se mostrará un cero insignificante en esa posición si fuera necesario. Al mismo tiempo, usamos el punto . para indicar que se debe mostrar el separador de decimales, con la misma consideración de configuración regional que señalamos hace unos momentos, pues aunque siempre indicamos este separador con un punto, el resultado final podría mostrar una coma dependiendo del país configurado.
#,#.0
Una variante de este mismo formato es indicar uno cero insignificante al a izquierda del decimal:
#,0.0
O bien, dos ceros insignificantes a la derecha del decimal
#,0.00
Toma nota de cómo el formato redondea el número visible dependiendo de cuántos dígitos le hayamos indicado que debe mostrar, pero no cambia el número original. Esto es una diferencia importante contra utilizar una fórmula como ROUND (o REDONDEAR en español), que sí cambia el valor de la celda.
Representar un número como fracciones y porcentajes
Otras configuraciones de formato de número personalizado muy interesantes incluyen cosas que tal vez no sabías que se podían hacer. Por ejemplo, ¿sabías que puedes formatear un número decimal como fracción sin tener que calcular absolutamente nada?
Para representar un número decimal como fracción sin cambiar el valor original de la celda, solamente tenemos que utilizar la diagonal / para indicar que se debe representar como una división. Dependiendo de cuánta precisión requiera la división, serán los dígitos que ocuparemos tanto para la parte entera como para la parte fraccionaria:
#,# #/####
Para representar el número como porcentaje, solo debemos usar el símbolo de porcentaje % que ya conocemos, y el formato hará el resto:
#%
Notación científica
De igual forma, para representar un número como notación científica, solo debemos usar E+ e indicar la precisión requerida con tantos ceros o signos de número correspondan:
0.00E+# "kg"
Miles y millones abreviados
OK, ahora algo muy curioso y a la vez útil. Si combinamos una etiqueta de texto en el formato con los dígitos y separadores de miles, podemos resumir números grandes como miles o millones simplemente agregando separadores de miles según convenga. Un número como 1500 se convierte entonces en 1.5K si aplicamos el siguiente formato:
0.0,"K"
Y 1500000 se convierte en 1.5M así:
0.0,,"M"
Formato de número personalizado positivo, negativo, cero y texto
Ahora entremos a algo que consideraría lo más avanzado en cuanto al formato de número personalizado, que es poner condiciones especiales para el mismo. Cabe aclarar que esto es diferente al formato condicional avanzado que ya conocemosque ya conocemos, y de hecho el formato de número personalizado se aplica antes que el formato condicional. Dentro del mismo formato de número personalizado es posible indicar cómo debe comportarse el formato dependiendo de si el número es positivo, negativo, si es cero o si es texto, todo en una misma regla de formato.
Esto se utiliza comúnmente en contabilidad para representar entre paréntesis números negativos, en vez de usar el signo de menos.
Para lograr esto, debemos aprender una regla de formato principal, que va así:
POSITIVO;NEGATIVO;CERO;TEXTO
No es necesario especificar todos los formatos, solo los necesarios de izquierda a derecha. Por eso hasta ahora hemos podido solamente usar el formato de números positivos sin problema.
Si queremos dar formato a números negativos también, usaremos solamente los primeros dos elementos de la regla de formato:
POSITIVO;NEGATIVO
Por ejemplo, para representar el número -1000 en negativo como paréntesis como acabamos de decir, el formato de número personalizado será:
0;(0)
Que combina dos formatos, un dígito, luego un punto y coma para indicar que seguirá otro formato, y el dígito entre paréntesis, dando como resultado que -1000 se representa como (1000)
Ahora agreguemos el formato que debe aplicar para cuando el valor sea cero, simplemente agregando un ; después del formato de negativo y luego la palabra “nada” entre comillas, indicando que debe mostrar ese texto en la celda aunque el valor real numérico siga siendo 0.
0;(0);"nada"
Por último, si agregamos el cuarto elemento de la regla de formato, estaremos indicando qué formato debe aplicar si llegara a encontrar texto en la celda en vez de números:
0;(0);"nada";"Texto: "@
En este caso, la arroba @ insertará cualquier texto que la celda incluya.
De esta manera, en una sola regla podemos indicar 4 diferentes situaciones para una misma celda dependiendo del valor, ¡genial!, ¿no crees? 😉
Formato de número personalizado condicional
No te vayas todavía pues todavía queda un poco más que podemos hacer con estas reglas de formato 😉. Una variante de esta misma regla es que podemos no solamente ajustar el formato para positivo, negativo y cero, sino que podemos hacerlo para que considere un rango preciso, si especificamos una condición con corchetes antes del formato. Por ejemplo, si quisiéramos que se mostrara un icono o emoji de “OK” junto con el número si es mayor o igual a 100, y uno de “Revisar” si está entre 50 y 100, solo debemos usar la regla así:
[>=100]"✅"#;[>=50]"❗"#;0;"⛔"@
Esto también lo podemos aprovechar para mostrar una unidad diferente dependiendo de si el valor está en el rango de los millones o de los miles:
[>=1000000]0.0,,"M";[>=1000]0.0,"K"
Colores
Y podemos ir todavía más allá, porque además de condiciones, podemos indicar colores para cada elemento de la regla de formato. Son algo limitados, pues solamente podemos elegir de entre los 56 colores base que las primeras versiones de Excel permitían, pero no deja de ser útil. Para poner un color a una regla de formato solo hay que especificarlo entre corchetes con el número de color correspondiente:
[Color50]0 ▲;[Red]-0 ▼;[Magenta]0 ▬
Como te puedes dar cuenta, hay algunos colores que podemos indicar con su nombre en inglés, como “Red”.
Para combinar los colores con formato condicional tenemos que poner primero el color y después la condición:
[Blue][>50]0 ▲;[Red]-0 ▼;[Magenta]0 ▬
Casos especiales
Existen algunos casos especiales que dependerán mucho de la idea que tengamos al aplicarlo, pues sus casos de uso no son inmediatamente evidentes.
Uno de ellos es que podemos usar un asterisco * para indicar que queremos que el caracter que le siga debe repetirse para llenar la celda hacia la derecha mientras tenga espacio.
#*⭐
Otro caso más es uno en el que necesitamos usar un caracter especial dentro de la regla del formato, como el mismo signo de número #, por ejemplo, que usado directamente más bien aplica el formato. Para usarlo solamente tenemos que escapar el caracter con una diagonal invertida:
\#0
Documentación
Como siempre, te recomiendo revisar la documentación oficial de Google Sheets al respecto de estos formatos de número personalizado, pues aunque cubrimos casi todas las variantes, siempre es bueno consultar las fuentes oficiales de la información:
- Ayuda de Google Docs y Google Sheets sobre Formato de número personalizado
- Formatos de fecha y número (Google Sheets API)
- Colores base permitidos para formato
¡Y listo! Ahora ya sabes cómo usar y aplicar el formato de número personalizado en Google Sheets para representar correctamente cualquier valor numérico en una celda.
Plantilla terminada para descargar
En la siguiente plantilla podrás encontrar todos los formatos de número personalizados listos para copiar y pegar:
¡Espero que te haya sido útil esta guía! No olvides seguirnos en YouTube para más tips, trucos y guías de productividad.
Alekz es un apasionado de la tecnología y los videojuegos. Además de ser locutor comercial, disfruta de la expresión artística más sastisfactoria y técnica que existe: programar (y pintar algo de pixel art). Fundó Tesel para ayudar a empoderar a las empresas a desarrollar su máximo potencial mediante la tecnología. Es un absoluto nerd de Star Trek.
Alekz es un apasionado de la tecnología y los videojuegos. Además de ser locutor comercial, disfruta de la expresión artística más sastisfactoria y técnica que existe: programar (y pintar algo de pixel art). Fundó Tesel para ayudar a empoderar a las empresas a desarrollar su máximo potencial mediante la tecnología. Es un absoluto nerd de Star Trek.
