Después de usar el mismo documento de hoja de cálculo por mucho tiempo para cualquier tarea, nos podemos dar cuenta de que lo utilizamos casi siempre de la misma manera, sobre todo si es un lugar donde registramos o consultamos datos muy seguido. Si tenemos muchas hojas o pestañas, algunos con muchas filas o columnas, puede llegar a ser muy tedioso navegarlas. Afortunadamente, existe una forma muy sencilla de crear vínculos dentro del documento para ir a celdas específicas, usando las fórmulas HYPERLINK y ADDRESS, y eso es lo que veremos hoy.
Cómo crear vínculos en Google Sheets con HYPERLINK
La primera fórmula que aprenderemos a usar será HYPERLINK (HIPERVINCULO en español). HYPERLINK nos permite crear un vínculo a cualquier dirección o URL que queramos, poniéndole un nombre. Google Sheets convertirá cualquier dirección a hipervínculo automáticamente, pero poniéndole un nombre con la fórmula HYPERLINK, todo se verá más limpio y legible.
=HYPERLINK(direccion, nombre)
Esto no tiene mucha complicación, pero es necesario tenerlo bien aprendido para lo que veremos ahora.
Crear vínculos a hojas o pestañas del documento
Ahora te voy a presentar un truco que nos será muy útil para navegar el documento. Supongamos que tenemos varias hojas o pestañas en nuestro documento, por ejemplo, una donde tenemos nombres de alumnos y otra donde registramos la asistencia de cada uno.
Fíjate muy bien en que cada vez que cambiamos de pestaña, la URL del documento cambiia un poco al final, específicamente en la parte que dice #gid= . Ese parámetro con su número asociado, corresponde al identificador de una hoja del documento actual, y lo podemos usar, entonces lo copiamos.
Vamos a crear una nueva pestaña que llamaremos Menú, y en una de las celdas, usaremos la fórmula HYPERLINK de esta manera, pegando el parámetro de la URL de la hoja con su identificador de esta manera:
=HYPERLINK("#gid=793592280","Alumnos")
Recuerda que el número debe corresponder a tu propia hoja.
Esto hará que HYPERLINK cree un vínculo con el texto “Alumnos”, digido al mismo documento donde estamos, pero a la hoja correspondiente a ese identificador. Si pasamos el mouse por encima y le damos click, nos llevará automáticamente a la hoja.
Crear vínculos a celdas específicas
Ahora, qué tal que quisiéramos referenciar a una celda específica y no solamente a una hoja. Esto sería muy útil por si hay mucha información en la hoja y necesitamos el enfoque en esa parte del documento sin tener que estarla buscando.
Si damos click derecho en cualquier celda y elegimos la opción Obtener enlace a esta celda, se copiará al portapapeles la dirección completa del documento con la referencia a esta celda específica:
Y aunque estemos en otra celda, nos posicionará ahí. Fíjate cómo ahora además del identificador de la hoja, hay un parámetro más llamado range, que contiene la referencia a la celda que nos interesa
Esto es súper útil, porque significa que también podemos recrear ese comportamiento utilizando la fórmula HYPERLINK en nuestro menú, si creamos una liga hacia la hoja de Asistencia, para que nos posicione en la celda A28
Crear un vínculo dinámico para moverse entre celdas
Bueno, ahora vamos a introducir otra fórmula que nos ayudará muchísimo con el siguiente paso: ADDRESS (DIRECCION en español). La fórmula ADDRESS nos regresa en forma de texto la referencia a cualquier celda que le indiquemos. La sintaxis nos dice que debemos especificar una fila, una columna, y algunos parámetros opcionales que dejaremos pendientes por ahora.
=ADDRESS(fila, columna)
Por ejemplo, si queremos el rango de la fila 3 y columna 4, la usaremos así:
=ADDRESS(3,4)
Y nos devolverá $D$3, con los signos de $ porque por default siempre regresa referencias absolutas, aunque esto se puede cambiar con los parámetros opcionales. Revisa la documentación de ADDRESS si te quedan dudas.
Entonces, esto nos va a ser útil porque si recordamos la guía donde revisamos una forma de obtener siempre la última fila o columna que no esté vacía, podemos crear una referencia dinámica para crear un vínculo que siempre apunte a la última fila que no esté vacía en una hoja determinada.
Recordando un poco y aplicando ese conocimiento a la hoja de Asistencia, esta es la fórmula que usamos en esa ocasión, pero sin INDEX, porque ahora no queremos el contenido de la celda, sino solamente el número de fila:
=ArrayFormula(MAX((Asistencia!A1:A<>"")*ROW(Asistencia!A1:A)))
Podemos ver que nos devuelve el número 28, porque esa es la última fila que tiene datos en nuestra hoja de asistencia.
Si combinamos esto con ADDRESS en donde va el número de fila y usamos 1 como el número de columna tendremos la referencia completa, es decir A28:
=ADDRESS(ArrayFormula(MAX((Asistencia!A1:A<>"")*ROW(Asistencia!A1:A))),1)
Ahora solo nos queda usar esto en nuestro menú con HYPERLINK para concatenar esto en el parámetro de range:
=HYPERLINK("#gid=67334941&range="&ADDRESS(ArrayFormula(MAX((Asistencia!A1:A<>"")*ROW(Asistencia!A1:A))),1),"Asistencia")
¡Y listo! Esto hará que cada vez que hagamos click en el vínculo, nos lleve a la última fila con datos de esa hoja, no importando si es la número 28 o la número 500. Esto nos ayudará muchísimo para no cansarnos tanto haciendo scroll con el mouse hacia abajo cada vez que queremos insertar un nuevo registro.
Guía en video
Si tienes dudas puedes ver esta misma guía explicada en video:
Espero que te haya sido útil esta guía! No olvides seguirnos en YouTube para más tips, trucos y guías de productividad.
Alekz es un apasionado de la tecnología y los videojuegos. Además de ser locutor comercial, disfruta de la expresión artística más sastisfactoria y técnica que existe: programar (y pintar algo de pixel art). Fundó Tesel para ayudar a empoderar a las empresas a desarrollar su máximo potencial mediante la tecnología. Es un absoluto nerd de Star Trek.
Alekz es un apasionado de la tecnología y los videojuegos. Además de ser locutor comercial, disfruta de la expresión artística más sastisfactoria y técnica que existe: programar (y pintar algo de pixel art). Fundó Tesel para ayudar a empoderar a las empresas a desarrollar su máximo potencial mediante la tecnología. Es un absoluto nerd de Star Trek.
