Una lista de tareas es una forma muy sencilla de llevar registro de cualquier actividad o proyecto. Además es muy útil cuando con alguna ayuda visual podemos saber a simple vista cuánto falta para que dicha actividad o parte del proyecto se complete. Hoy toca hacer algo sencillo pero muy práctico en Google Sheets: una lista de tareas. Con un poco de ingenio, formato y algunas fórmulas, podremos también marcar el avance de cada tarea y reflejarlo en una muy bonita barra de progreso dinámica.

Preparar nuestros datos

Primero, como siempre vamos a preparar nuestra hoja en un documento nuevo. Aquí escribiremos en la segunda columna el título de nuestra lista, que por ahora mantendremos genérico. Escribimos también algunas tareas comenzando en la cuarta fila para darnos espacio necesario para poner la barra de progreso, y en la primera columna insertamos casillas de verificación correspondientes a las tareas actuales y futuras.

Esta es la versión más básica de una lista de tareas, pero está un poco simplona, no lo crees? ¡Vamos a mejorarla un poco! ;D De aquí en adelante las cosas se van a ir poniendo más interesantes, prácticas y bonitas. 😉

Agregar una barra de progreso a una lista de tareas en Google Sheets

Lo primero que queremos agregar es una forma de medir el progreso de esta lista. Para lograrlo, vamos calcular el porcentaje de tareas completadas usando la fórmula COUNTIF (o CONTAR.SI en español) aplicada al rango de las casillas de verificación, que nos regresará cuántas de estas tienen valor de TRUE, y luego dividiendo este número entre el número de tareas en el rango donde están listadas usando la fórmula COUNTA (CONTARA en español), que nos devuelve el número de valores en un rango. Te preguntarás ¿por qué no usamos simplemente COUNT (CONTAR en español)? Eso es porque COUNT solamente puede contar valores numéricos.

=COUNTIF(A4:A,TRUE)/COUNTA(B4:B)

Si le damos formato de porcentaje sin decimales para que sea más claro, ya quedó listo por ahora.

Fíjate también en que no estamos indicando una fila final en los rangos, para poder agregar cualquier número de tareas hacia abajo.

Ahora sí, ya que tenemos este número, pasemos a representarlo visualmente como una barra de progreso. Para esto nos servirá muchísimo usar la función de SPARKLINE, que hemos visto antes en otra guía. Esta función dibuja una gráfica sencilla dentro de una celda, y con esa gráfica simularemos una barra de progreso o avance.

=SPARKLINE(COUNTIF(A4:A,TRUE),{"charttype","bar";"max",COUNTA(B4:B)})

Si te fijas bien, estamos usando el mismo principio que usamos para calcular el porcentaje, pero ahora el número de tareas completadas se lo entregamos a SPARKLINE como los datos de entrada, y en las opciones de la gráfica usamos “bar” (osea barras) como tipo de gráfica y le indicamos que el máximo será justamente el número de elementos en la lista.

¡Vamos bien! Ahora cada vez que agreguemos tareas o completemos alguna de ellas, se actualizará la barra de progreso dinámicamente.

OK, esto funciona bien, pero hay algunos detalles que hay que arreglar primero. Si me has ido siguiendo, te darás cuenta de que si activas una casilla que no tenga tarea correspondiente todavía, el porcentaje se pasará de 100%, y eso no tiene mucho sentido.

Además, si no hay tareas, nos mostrará un error porque estará intentando dividir entre 0, y tampoco queremos eso.

No te preocupes, lo arreglamos fácilmente cambiando la fórmula del indicador de porcentaje así, usando IFERROR para mostrar 0 si sale el error que acabamos de mencionar y poniendo la condición de que si la operación es mayor a 1, simplemente mostremos 1, que en nuestro formato de porcentaje es nuestro 100%. Si no es mayor a 1, mostramos el valor de la división como siempre.

=IFERROR(IF(COUNTIF(A4:A,TRUE)/COUNTA(B4:B)>1,1,COUNTIF(A4:A,TRUE)/COUNTA(B4:B)),0)

Así, ya estamos libres de estos errores. 😉

Dar formato a la lista de tareas

OK, ya tenemos una lista de tareas bastante funcional, pero yo creo que si nos esforzamos un poco en la parte estética, podemos lograr que se vea todavía mejor, ¿no te parece? 🙂

Primero, démosle un color personalizado a la barra de progreso. Para eso solamente modificamos un poco la fórmula de SPARKLINE, agregando la opción de “color1” y el código de color en hexadecimal que más nos guste:

=SPARKLINE(COUNTIF(A4:A,TRUE),{"charttype","bar";"max",COUNTA(B4:B);"color1","#8254cb"})

Ahora, vamos a aplicar varias cosas relacionadas al formato. La primera que hará que todo se vea más limpio es ir al menú Ver – Mostrar – Líneas de cuadrícula y desactivar esa opción.

Realmente depende de ti personalizar esta hoja como más te guste, pero te voy a enlistar algunas sugerencias de formato que yo hice que me parecieron que la hacen más agradable a la vista:

• Darle un borde a la celda de progreso

• Hacer que la celda del porcentaje esté alineada a la izquierda

• Hacer la fuente más grande en el título y en el porcentaje, así como hacer las filas verticalmente más grandes, para dar más espacio alrededor y que salten a la vista más.

• Aplicar un centrado horizontal y centrado vertical en título y en el porcentaje con el menú de Formato – Alineación – Centro y Formato – Alineación – Medio

• Seleccionar todas las filas de tareas que vayamos a usar y ajustar el tamaño vertical, así como centrarlas verticalmente

También podemos divertirnos un poco aplicando colores alternos en el menú Formato – Colores alternos con nuestro rango completo de tareas A4:C1000

Y, ¿por qué no? También algo de Formato condicional en el mismo rango A4:C1000, utilizando la fórmula personalizada

=$A4

La cual coloreará la fila correspondiente al rango elegido solamente si la casilla está activada. En el estilo elegimos algún color de fondo que nos guste para representar a la tarea completada, le decimos que queremos que la palabra esté tachada y cambiamos también el color de la letra a gris.

¡Quedó muy bien! ¿No lo crees? 😉

Lista de tareas avanzada con opciones “Por hacer” “En progreso” y “Terminada”

No te vayas todavía, porque vamos a ir un paso más allá para llevar nuestras listas de tareas con barras de progreso al siguiente nivel.

Ahora vamos a crear una modalidad un poco más avanzada de la misma lista. Cada tarea o actividad tendrá la opción de estar en uno de estos tres estados: “Por hacer”, “En progreso” o “Terminada”. Para eso, solamente tenemos que elegir el rango donde están nuestras casillas de verificación e ir al menú Insertar – Menú desplegable. Aquí configuramos nuestras tres opciones justo como acabamos de decir, con colores diferentes que representen cada estado de la actividad, por ejemplo, gris, amarillo y verde correspondiente a “Por hacer” “En progreso” y “Terminada”.

También convendría aplicar reglas similares de formato condicional dependiendo de la opción, justo como hicimos hace un rato, pero ahora con las fórmula personalizadas que correspondan a cada opción. Te las muestro aquí:

=IF($A4="Terminada",TRUE)

=IF($A4="En progreso",TRUE)

=IF($A4="Por hacer",TRUE)

El estilo de cada categoría lo dejo a tu gusto 🙂

El último detalle que hará que esta lista brille realmente, es esta fórmula que aplicaremos a la barra de progreso para que nos muestre el avance de cada categoría de tarea por separado dentro de la misma celda.

=SPARKLINE( {COUNTIF(A4:A,"Terminada"),COUNTIF(A4:A,"En progreso")},{"charttype","bar";"max",COUNTA(B4:B);"color1","#0f6743";"color2","#fff2cc"})

Nota aquí que como este tipo de gráfica miniatura en SPARKLINE solamente nos permite agregar dos colores para los datos, el tercer color será el color de fondo de la celda, que coincidirá con el de “Por hacer”.

Puedes agregar también un pequeño conteo que podría ser útil.

Lista de tareas avanzada con diferentes etapas o categorías de proyecto

Por último, con este mismo conocimiento podemos crear una combinación de listas de tareas que comprendan varias etapas o categorías de un proyecto. Cada una de estas etapas puede tener su propia barra de progreso, y también habrá una barra de progreso principal que sume todas las etapas.

Te comparto la fórmula de la barra de progreso principal si quieres acomodar la hoja igual que yo. El único cambio es que sumé cada conteo por separado en la parte del número máximo de tareas en SPARKLINE:

=SPARKLINE( {COUNTIF(A5:A,"Terminada"),COUNTIF(A5:A,"En progreso")},{"charttype","bar";"max",(COUNTA(B5:B14)+COUNTA(B17:B26)+COUNTA(B29:B38)+COUNTA(B41:B50));"color1","#0f6743";"color2","#fff2cc"})

Y también, la fórmula de cada barra de progreso individual por etapa:

=SPARKLINE( {COUNTIF(A5:A14,"Terminada"),COUNTIF(A5:A14,"En progreso")},{"charttype","bar";"max",COUNTA(B5:B14);"color1","#0f6743";"color2","#fff2cc"})

=SPARKLINE( {COUNTIF(A17:A26,"Terminada"),COUNTIF(A17:A26,"En progreso")},{"charttype","bar";"max",COUNTA(B17:B26);"color1","#0f6743";"color2","#fff2cc"})

=SPARKLINE( {COUNTIF(A29:A38,"Terminada"),COUNTIF(A29:A38,"En progreso")},{"charttype","bar";"max",COUNTA(B29:B38);"color1","#0f6743";"color2","#fff2cc"})

=SPARKLINE( {COUNTIF(A41:A50,"Terminada"),COUNTIF(A41:A50,"En progreso")},{"charttype","bar";"max",COUNTA(B41:B50);"color1","#0f6743";"color2","#fff2cc"})

La consideración que tenemos que hacer aquí es que ahora los rangos de las fórmulas por etapa serán fijos y tendrán una cantidad determinada máxima de tareas, para poder agruparlas y así poderlas mostrar y esconder fácilmente a nuestro gusto.

¡Y listo! Ahora ya sabes cómo hacer listas de tareas o actividades para tus proyectos utilizando barras de progreso dinámicas que se actualizan automáticamente. Esto te debe servir mucho para organizarte mejor. 😀

Plantilla terminada para descargar

Guía en video

Si tienes dudas puedes ver esta misma guía explicada en video

¡Espero que te haya sido útil esta guía! No olvides seguirnos en YouTube para más tips, trucos y guías de productividad.

Si te interesa aprender más sobre Google Sheets, checa nuestro Curso: Aprende Sheets en el que podrás elevar tu aprendizaje de hojas de cálculo al nivel experto.

Alekz

Alekz es un apasionado de la tecnología y los videojuegos. Además de ser locutor comercial, disfruta de la expresión artística más sastisfactoria y técnica que existe: programar (y pintar algo de pixel art). Fundó Tesel para ayudar a empoderar a las empresas a desarrollar su máximo potencial mediante la tecnología. Es un absoluto nerd de Star Trek.

Alekz

Alekz es un apasionado de la tecnología y los videojuegos. Además de ser locutor comercial, disfruta de la expresión artística más sastisfactoria y técnica que existe: programar (y pintar algo de pixel art). Fundó Tesel para ayudar a empoderar a las empresas a desarrollar su máximo potencial mediante la tecnología. Es un absoluto nerd de Star Trek.